EncryptPad.pro.in

QT       += core gui widgets printsupport svg
PROJ = ../..
VPATH = $$PROJ/qt_ui

EXE_LINKS_TO = %{library_target} %{link_to}

# botan
BOTAN_LDFLAGS = %{botan_ldflags}
BOTAN_CXXFLAGS = %{botan_cxxflags}
LIBS += $$BOTAN_LDFLAGS

LIBS += $$EXE_LINKS_TO

# encryptmsg
ENCRYPTMSG_LDFLAGS = %{encryptmsg_ldflags}
ENCRYPTMSG_CXXFLAGS = %{encryptmsg_cxxflags}
LIBS += $$ENCRYPTMSG_LDFLAGS
QMAKE_CXXFLAGS += $$ENCRYPTMSG_CXXFLAGS

# zlib
LIBS += %{zlib_ldflags}

#bzip2
LIBS += %{bzip2_ldflags}

QMAKE_CXXFLAGS += $$BOTAN_CXXFLAGS

LIBS += %{cxx_abi_flags}
LIBS += %{ldflags}

QMAKE_CXXFLAGS += -DFAKEVIM_STATIC_DEFINE

CONFIG(debug, debug|release){
    CONFIG_NAME = debug
    SUBDIR_RELEASE =
}

CONFIG(release, debug|release){
    CONFIG_NAME = release
    SUBDIR_RELEASE = RELEASE=on
}

# install
sources.files = $$SOURCES $$HEADERS $$RESOURCES $$FORMS EncryptPad.pro images
# INSTALLS += target sources

CONFIG += c++11

FORMS += \
    set_key_dialog.ui \
    file_properties_dialog.ui \
    new_key_dialog.ui \
    preferences_dialog.ui \
    find_and_replace.ui \
    get_passphrase_dialog.ui \
    confirm_passphrase_dialog.ui \
    get_passphrase_or_key_dialog.ui \
    file_encryption_dialog.ui \
    passphrase_generation_dialog.ui \
    find_dialog.ui

QMAKE_CXXFLAGS += -D_FILE_OFFSET_BITS=64

INCLUDEPATH += $$PROJ/build/include
INCLUDEPATH += $$PROJ/deps/plog/include
INCLUDEPATH += $$PROJ/deps/tinyexpr

SOURCES += \
    application.cpp \
    file_name_helper.cpp \
    main.cpp \
    mainwindow.cpp \
    set_key_dialog.cpp \
    set_passphrase_dialog.cpp \
    async_load.cpp \
    plain_text_switch.cpp \
    file_properties_dialog.cpp \
    new_key_dialog.cpp \
    preferences_dialog.cpp \
    recent_files_service.cpp \
    find_and_replace.cpp \
    get_passphrase_dialog.cpp \
    confirm_passphrase_dialog.cpp \
    get_passphrase_or_key_dialog.cpp \
    set_encryption_key.cpp \
    file_encryption_dialog.cpp \
    m_window_load_adapter.cpp \
    file_encryption_dlg_adapter.cpp \
    file_dlg_async.cpp \
    passphrase_generation_dialog.cpp \
    load_save_handler.cpp \
    file_request_service.cpp \
    plain_text_edit.cpp \
    find_dialog.cpp \
    preferences.cpp \
    fake_vim_edit.cpp \
    fake_vim_wrapper.cpp \
    line_number_area.cpp \
    calculator.cpp \
    ../deps/tinyexpr/tinyexpr.c \

HEADERS += \
    application.h \
    file_name_helper.h \
    mainwindow.h \
    set_key_dialog.h \
    set_passphrase_dialog.h \
    async_load.h \
    plain_text_switch.h \
    file_properties_dialog.h \
    new_key_dialog.h \
    preferences_dialog.h \
    recent_files_service.h \
    find_and_replace.h \
    get_passphrase_dialog.h \
    confirm_passphrase_dialog.h \
    get_passphrase_or_key_dialog.h \
    set_encryption_key.h \
    file_encryption_dialog.h \
    m_window_load_adapter.h \
    file_encryption_dlg_adapter.h \
    file_dlg_async.h \
    passphrase_generation_dialog.h \
    load_save_handler.h \
    file_request_service.h \
    plain_text_edit.h \
    common_definitions.h \
    find_dialog.h \
    preferences.h \
    fake_vim_edit.h \
    fake_vim_wrapper.h \
    line_number_area.h \
    calculator.h \
    ../deps/tinyexpr/tinyexpr.h \

QMAKE_RESOURCE_FLAGS += -no-compress
RESOURCES += \
    EncryptPad.qrc \
    culture.qrc

TRANSLATIONS = \
    ../../qt_ui/encryptpad_en_gb.ts \
    ../../qt_ui/encryptpad_ru_ru.ts \
    ../../qt_ui/encryptpad_fr_fr.ts \
    ../../qt_ui/encryptpad_lt_lt.ts \
    ../../qt_ui/encryptpad_zh_cn.ts

RC_FILE = $$PROJ/qt_ui/encrypt_pad.rc
DESTDIR = $$PROJ/bin/$$CONFIG_NAME
OBJECTS_DIR = $$CONFIG_NAME/obj
unix|win32:TARGET = encryptpad
macx:TARGET = EncryptPad

include($$PROJ/deps/fakevim/fakevim/fakevim.pri)