gradle-git/build.gradle at master · gavares/gradle-git · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
buildscript {
	repositories {
		mavenCentral()
		maven { url 'https://oss.sonatype.org/content/groups/public/' }
	}
	dependencies { classpath 'org.ajoberstar:gradle-git:0.2.0-SNAPSHOT' }
}

apply plugin: 'groovy'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'github-pages'

group = 'org.ajoberstar'
description = 'Git plugins for Gradle'
version = '0.2.0'

repositories {
	mavenCentral()
}

dependencies {
	groovy localGroovy()
	compile gradleApi()
	compile 'org.eclipse.jgit:org.eclipse.jgit:2.0.0.201206130900-r'
	compile 'org.eclipse.jgit:org.eclipse.jgit.ui:2.0.0.201206130900-r'
}

githubPages {
	repoUri = 'git@github.com:ajoberstar/gradle-git.git'
	pages {
		from(javadoc.outputs.files) {
			into 'docs/javadoc'
		}
		from(groovydoc.outputs.files) {
			into 'docs/groovydoc'
		}
	}
}

task sourcesJar(type:Jar) {
	classifier = 'sources'
	from sourceSets.main.allSource
}

task javadocJar(type:Jar) {
	classifier = 'javadoc'
	from javadoc.outputs.files
}

task groovydocJar(type:Jar) {
	classifier = 'groovydoc'
	from groovydoc.outputs.files
}

artifacts {
	archives sourcesJar
	archives javadocJar
	archives groovydocJar
}

signing {
	sign configurations.archives
}

uploadArchives {
	repositories.mavenDeployer {
		name = 'Sonatype OSS'
		repository(url:'https://oss.sonatype.org/service/local/staging/deploy/maven2') {
			authentication(userName:sonatypeUserName, password:sonatypePassword)
		}
		snapshotRepository(url:'https://oss.sonatype.org/content/repositories/snapshots') {
			authentication(userName:sonatypeUserName, password:sonatypePassword)
		}

		beforeDeployment { signing.signPom it }

		pom.project {
			name project.name
			description project.description
			url 'http://github.com/ajoberstar/gradle-git'
			licenses {
				license {
					name 'The Apache Software License, Version 2.0'
					url 'http://www.apache.org/licenses/LICENSE-2.0'
				}
			}
			developers {
				developer {
					id 'ajoberstar'
					name 'Andrew Oberstar'
					email 'andrew@ajoberstar.org'
				}
			}
			scm {
				connection 'git://github.com/ajoberstar/gradle-git.git'
				developerConnection 'git@github.com:ajoberstar/gradle-git.git'
				url 'http://github.com/ajoberstar/gradle-git'
			}
		}
	}
}